在执行方法中，遇到复杂的参数类型（比如 record ）必须带上RTTI类型信息。

例子如下：

type
  TMsgInfo =  record
    MsgInfo:string;
    MsgID:Integer;
  end;
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
   procedure ShowMsg(MsgInfo:TMsgInfo);
  end;

procedure TForm1.ShowMsg(MsgInfo: TMsgInfo);
begin
  ShowMessageFmt('ID:%d Msg:%s',[MsgInfo.MsgID,MsgInfo.MsgInfo]);
end;

RTTI 执行调用：

procedure TForm1.Button1Click(Sender: TObject);
var
  RT:TRttiType;
  RM:TRttiMethod;
  MsgInfo:TMsgInfo;
  Value:TValue;
begin
  RT := TRttiContext.Create.GetType(TypeInfo(TForm1));

  RM := RT.GetMethod('ShowMsg');
  if RM<>nil then
  begin
    MsgInfo.MsgID := 100000;
    MsgInfo.MsgInfo := 'SEWGWEG';

   // 构造 TValue 复杂参数

    TValue.Make(@MsgInfo,TypeInfo(TMsgInfo),Value);
    RM.Invoke(self,[Value]);
  end;
end;

丢人的CSDN，就这么点技术和管理水平，还号称中国程序员大本营!

鄙视！！！下面图片是群里发布的！

因为程序员具有一种深入骨髓的惰性，与年龄日益增长，懒惰和保守遮住了delphi在细节上无微不至的进步！

关于动态绑定事件，老版本当然也可以实现，一个是实现相同的参数名称，直接赋值；另外一个是用TMethod.Code和TMethod.data动态绑定事件，也许还有其他方法，但是，D7是不能用匿名方法来动态绑定事件。Delphi XE 完美实现了匿名方法来动态绑定事件，而匿名方法和事件一起绑定，在程序代码上感觉是一体的；当然，如果匿名方法很长，可以单独声明！

下面请看动态绑定 TEdit.OnChage事件：

///动态绑定 Tedit事件
  @edt1.OnChange :=
   pPointer(Cardinal(pPointer(
     procedure (sender: tObject)
     begin
       ((sender as TEdit).Owner as TForm).Caption :=
        (sender as TEdit).Text;
     end )^ ) + $0C)^;

//复杂点事件参数，比如窗体的OnQuery事件

@Self.OnCloseQuery :=
    pPointer(Cardinal(pPointer(
      procedure (Sender: TObject; var CanClose: Boolean)
      begin
        CanClose := Application.MessageBox('你确定要关闭主窗口吗？','关闭提示',MB_OKCANCEL+MB_ICONQUESTION) = IDOK;
      end )^ ) + $0C)^;

运行效果图：

其中有个CIS SMTP 发送邮件的例子，发送中文邮件，乱码很厉害！

其实只要指定编码格式，黑体的部分，中文乱码即可解决！

procedure TForm1.btnSendClick(Sender: TObject);
begin
  if (clSmtp1.Active) then Exit;

  clSmtp1.Server := edtServer.Text;
  clSmtp1.Port := StrToInt(edtPort.Text);

  clSmtp1.UserName := edtUser.Text;
  clSmtp1.Password := edtPassword.Text;

  if cbUseTLS.Checked then
  begin
    clSmtp1.UseTLS := ctAutomatic;
  end else
  begin
    clSmtp1.UseTLS := ctNone;
  end;

  clSmtp1.Open();
  try
    clMailMessage1.CharSet := 'UTF-8';//请注意，，UTF-8写法很混乱，如果写成 UTF8，那是很杯具！
    clMailMessage1.Encoding :=  cmBase64; //加密方式

    clMailMessage1.BuildMessage( memBody.Text, '');
    clMailMessage1.From.FullAddress := edtFrom.Text;
    clMailMessage1.ToList.EmailAddresses := edtTo.Text;
    clMailMessage1.Subject := edtSubject.Text;

    clSmtp1.Send(clMailMessage1);

    ShowMessage('The message was sent successfully.');
  finally
    clSmtp1.Close();
  end;
end;

运行示例图：

在foxmail浏览邮件，正常显示：

Delphi XE2 不仅带来一个全新的 2D/3D UI 框架，跨平台IOS，其他方面的改进也是不容小视，比如 RTTI的日趋完善。新版本的XE2支持了 TRttiIndexedProperty 和 加强RTL的反射（支持WIN32/WIN64/MAC）！

Delphi有一种特殊的属性值，叫索引属性，常见的 TCollection 类的 Items[Index] 就是索引属性，在D2010/XE版本中，常常为RTTI 不能反射此属性而抱憾和愤青！今天，XE2版本终于可以反射此属性了。比如针对TDBGrid.TDBGridColumns 凭此功能，我们可以轻松反射其l索引属性(列的标题)并做出多国语言功能。

 uses System.RTTI;

procedure TForm1.Button1Click(Sender: TObject);
var
  RX:TRttiContext;
  RT:TRttiType;
  RP:TRttiProperty;
  RIP:TRttiIndexedProperty;
  Value:TValue;
  i,iCount:Integer;
  Col:TColumn;
begin
  RX := TRttiContext.Create;
  RT := RX.GetType(TDBGridColumns.ClassInfo);
  RP := RT.GetProperty('Count');
  iCount := RP.GetValue(DBGrid1.Columns).AsInteger;

  for RIP in RT.GetIndexedProperties do
  begin
    if RIP.PropertyType.Handle = TypeInfo(TColumn) then
    begin
      ListBox1.Items.Add(RIP.Name+ ':'+RIP.ToString);

      for I := 0 to iCount - 1 do
      begin
        Value := RIP.GetValue(DBGrid1.Columns,[i]);
        Col := Value.AsObject as TColumn;
        ListBox1.Items.Add(Col.Title.Caption);
      end;
    end;
  end;

end;

运行效果图

如图：

正是因为 Delphi 单元不认识UTF8字符集，导致单引号被吃掉，编译异常！

这个时候，千万不要随便修改或保存该单元文件。将该单元拖到 NodePad++里，在 NodePad++ 菜单->格式->以UTF8显示，即可看到这样的效果，UTF8字符编码马上原形毕露（如图：xC0，xFF， 记住这是十六进制，是零而不是大写字母的O）：

以 #$ 打头，修正如下：

如果是char字符，则改为  #$00C0和 #$00FF，记住多两个零。

如果是ansichar，则改为 #$C0和 #$FF。

我经历的一些控件： ICS 7.0, SynEdit, Database Comparer VC 都有这个UTF8编码问题。

摆平她们，然后享受她们！

本文以  http://code.google.com/p/tangram-plugin-framework/ 插件框架自带的BPL包合并向导工具做一次图文介绍！

1、安装好开源插件框架 tangram-plugin后，然后点击 菜单 File->New->Others，找到tangram FrameWork里的包合并向导，

2、Dev控件堪称独孤求败，最强也是最肥的数据库解决方案。我们以Dev套件包为准，合并Dev几十个BPL包为一个BPL包。

这里用到dev功能是cxGirid，treelist和垂直表格，如果用到其他的功能，涉及的BPL会有所不同！

选择单元

3、生成DPK工程，改名为Dev.BPL，记得保存。DPK文件如果没有生成，请先带一个空白工程，然后再用向导生成DPK，即重复上面的步骤。生成DPK后，再移除原来的DPR工程。

4、有可能碰到重复的单元，已经在别的包被引用了，我们的原则是，只封装Dev的单元。

（Dev的单元名好区分，都是以cx或dx打头。）比如sysInit，在 contains 按 CTRL+Y删除即可。

    去年写的一篇文章《Delphi2010发布日。。。》，引起了众多delphi fans的一些共鸣！D2010确实是一件里程碑的重大事件！

    今年8月Delphi Xe悄悄来了，但似乎没有像delphi2010那么反响大！

    在我看来，delphi XE只是D2010的SP6补丁，既然是补丁，稳定性肯定更好，只是没有太多的新鲜亮点！XE修复最多的还是泛型问题，以及VCL类库和RTL核心。

    Delphi XE最大亮点是Builder 速度比D2010快了一倍左右，Code Inside功能比D2010快，这个还做的真不错！XE完全兼容D2010，稳定性也不错，应该是D2010最佳替代品！如果非要在硬盘上只能留一个delphi版本，那只能是Delphi XE！谁叫他那么邪恶呢？

    只是，令人惋惜的是，D2010的RTTI开辟了一个新天地，在XE中竟然没有得到发展或修正问题。诸如，XE的RTTI还不支持 类属性、常量、数组属性等。

    根据发展路线图看，delphi XE本来承载跨平台的伟大任务，估计人手问题，加上CodeGear产品阵线太庞大，应接不暇，导致不得不在后期在XE砍掉跨平台内容！

    在我看来，delphi XE是Win32 + Unicode 最后一个经典版本，之后便进入了Win64+跨平台+多核多线程时代！微软估计也不想看到这样的结果，不过，谁叫微软丢了原生语言开发而去捡了“托管语言平台”这个烂芝麻呢！再说一下微软，在VS2010中，微软终于有点醒悟了，增强了对VC2010的原生语言开发。只是令人搞笑的是，VC2010终于有了Ribbon菜单的可视化开发，这等小事，竟然大肆渲染！

    再说一下易博龙的销售问题！随着中国delphi fans老去，新人接不上来，delphi人才变得青黄不接！更令人叹息的是，易博龙还实行价格歧视政策（跟ThinkPad有的一比），2999美元企业版的价格在大陆要卖3-4万一套，比较低廉的个人版和专业版不能再大陆售卖。要说易博龙中国能做点服务也可以值这个钱了，但是，一来没有中文版帮助或其他汉化的文献，二来所谓的服务只是一手交钱一手交货的服务，真不知道易博龙中国存在的理由是什么。

    而易博龙所谓的增值计划，都是买新产品送老产品，诸如买XE送D2010/D2007，这又不是天朝冰箱里冻了一年的猪肉的那么值钱，实在令人哭笑不得！一年一个版本的发展计划，让购买者犹豫不决，而易博龙开发者疲以奔命新项目开发和不断出现的Bug。

    如果你想购买delphi 新版本，XE倒是不错的选择，支持泛型、RTTI反射、Unicode，你用过了就不会再缅怀经典的D7版本！如果你买了D2010，不想再升级到XE的话，我还是鼓励你使用盗版的XE，放弃D2010。你可以有理由跟他们说，把一个属于D2010的补丁当做新产品来卖，你是不甘心的。如果你还一直使用D7的话，建议你起码要升级到D2007，因为D2007是win32+ansi的最后经典版本，完全兼容D7！当然，要跟上世界潮流，建议你试试一下XE盗版。当然，如果你做软件发财了，良心发现一下吧，支持一下正版吧！

    其实真的非常希望易博龙能调整销售策略，与其维持大陆惨淡的销售人气，不如一视同仁，北美和大陆一个价格、一种销售方案；培养和留住开发人员，这才是立足之本！

    当企业级应用越来越要求更高更好的体验，当浏览器像老牛慢车一样扛不住BS的胖客户端应用，假以时日，内存条越来越便宜，个人电脑8G-16G内存比比皆是，WIN64迅速推广开了，桌面三层的企业级应用会推向一个新的高潮！请相信，Delphi还会迎来一个美好的明天！

当后台使用UniDAC+CDS，关联视图或自定义函数，为了数据一致性，有可能需要在前台界面上修改CDS相关的自定义函数输出的字段，即便是将 该字段设置为 readonly为false，或将其字段的 FieldDefs属性的attributes的faReadOnly去掉，系统也会抛出一个异常：trying to modify read-only Field。

解决问题很简单，将TUniQuery.Options.SetFieldsReadOnly为false即可。

查一下TUniQuery.Options.SetFieldsReadOnly的帮助，这样写道：

If True, dataset sets the ReadOnly property to True for all fields that do not belong to UpdatingTable or can not be updated. Set this option for datasets that use automatic generation of the update SQL statements only.

移除皮肤包很容易，干脆在菜单Component->Install Packages直接删除算了（当然也可以将勾选去掉）。

但是使用 Remobjects Hydra + DevExpress（6.52）发现一个问题，dxSkinsCore, dxSkinsDefaultPainters, dxSkinscxPCPainter这四个单元总是阴魂不散附加在interface区域的单元里，删也删除不掉。由于有了这四个莫须有的单元，我又懒得再加载相关的皮肤包，导致每次系统退出时候总是有内存泄露问题。经研究，在菜单->Project->Modify Skin Options 设置成如下图

再删除替换整个工程组（EXE+DLL）的dxSkinsDefaultPainters, dxSkinscxPCPainter四个单元，再也没有内存泄露！

         乔丹职业在95-98年赛季，公牛队开出了震撼全世界体坛的合同给乔丹，3年一个亿美元，年薪3300多万美元，按照现在的通货膨胀率， 至少年薪5000万美元。整个一年赛季，乔丹赚了8千万美元，成为最富有的体育运动员。如今，詹姆斯+韦德+波什，成为最富有最激情的新三巨头，将会开创一个属于他们未来的最好时代，当然，这也是其他29支队伍最坏的时代！

INSERT INTO E_UserPhoto(UserID, CreateTime,UpdateTime,Photo)
   SELECT 7,GETDATE(),GETDATE(),
   * FROM OPENROWSET(BULK N'C:\Users\Administrator\Pictures\a.jpg', SINGLE_BLOB)
   as photo

请注意，获取BLOB字段后必须用字段别名命名，如 As Photo，否则会有以下错误：

必须在 FROM 子句中为大容量行集指定相关名称。

       有那么一种常量，你希望常量的名称和真实的常量值一样，比如，用于作配置文件的常量。当然，如果你不觉得辛苦，一般来说，常量名和常量值逐个敲出来，也无可厚非。但是，如果你还在使用D2010作开发而不发挥新RTTI技术，很显然，你已经Out了，不随波逐流使用新技术，连“走马观花”赏花的机会也没有。

     为了方便管理常量，我们需要声明一个记录类型。为啥使用记录类型而不是类呢？因为记录类型不用创建和释放，其次，记录比类更节省系统资源。

    //参数的名称信息，用于常量设置，都是字符串
TParamName = record
    Socket:string;
    System:string;
    DBConfig:string;
    //通讯参数
    ThreadCount:string;
    Port:string;
    SessionLife:string;
    TimeOut:string;
    ZipRate:string;
    Encrypt:string;
    //系统参数
    AutoRun:string;
    SocketLog:string;
    BusinessLog:string;
    DBLog:string;
    //数据库配置
    Server:string;
    Provider:string;
    DataBase:string;
    DBPort:string;
    UserName:string;
    UserPswd:string;
    Pooling:string;
    PoolMax:string;
    PoolMin:string;
    PoolLife:string;
end;

------------我们使用一个新的方法管理 记录类型的 RTTI--------------------------------------

uses RTTI;

function TRttiInfo.SetRecordDeftValue(TypeInfoValue, RecValue: Pointer): Boolean;
var
RTX:TRttiContext;
RT:TRttiType;
RF:TRttiField;
iCount:Integer;
begin
Result := False;
try
    RTX := TRttiContext.Create;
    RT := RTX.GetType(TypeInfoValue);
    iCount := 0;
    for RF in RT.AsRecord.GetFields do
    begin
        RF.SetValue(RecValue,RF.Name);
        Inc(iCount);
    end;
    Result := iCount >0;
finally
    RTX.Free;
end;

end;

--------------调用就非常简单，需要指针来辅助参数传输了---------------

var

   SysParamName:TParamName ;//记录声明

调用：

    RttiInfo.SetRecordDeftValue(TypeInfo(TParamName),@SysParamName);

    1、 由于记录类型是一个抽象的类型，没有具体的类型名，因此需要借助 TypeInfo来获取类型信息

   2、通过 @SysParamName 获取指定记录的地址。

很简单吧，希望能对你有点帮助！

     数据集字段信息，是一个完整的字典信息。因此，我们在JSON必须也建立字典信息，才能创建数据集的字段信息。我们设置其JSON信息如下：

   COLS:[字段列表信息]，如：

"Cols":[{"JsonType":"integer","FieldIndex":0,"FieldType":"Integer","FieldSize":0,"FieldName":"ID","Required":false},{"JsonType":"string","FieldIndex":1,"FieldType":"String","FieldSize":100,"FieldName":"Title","Required":false},{"JsonType":"variant","FieldIndex":2,"FieldType":"Blob","FieldSize":0,"FieldName":"Picture","Required":false}]

数据信息以Data做节点，也是一个数组嵌套记录信息：

"Data":[记录集信息]

废话少说，直接上代码：

unit uDBJson;

interface
uses
SysUtils,Classes,Variants,DB,DBClient,SuperObject;

type
TTableJSon = class

private
    const cstFieldType = 'FieldType';
    const cstFieldName = 'FieldName';
    const cstFieldSize = 'FieldSize';
    const cstJsonType = 'JsonType';
    const cstRequired = 'Required';
    const cstFieldIndex = 'FieldIndex';

    const cstCols= 'Cols';
    const cstData= 'Data';

public
    class function JSonFromDataSet(DataSet:TDataSet):string;
    class function CreateFieldByJson(Fields:TFieldDefs;ColsJson:ISuperObject):Boolean;
    class function ImportDataFromJSon(DataSet:TDataSet;DataJson:ISuperObject):Integer;
    class function CDSFromJSon(CDS:TClientDataSet;Json:ISuperObject):Boolean;
    class function GetValue(Json:ISuperObject;const Name:string):Variant;

    class function CreateJsonValue(Json:ISuperObject;const Name:string;const Value:Variant):Boolean;
    class function CreateJsonValueByField(Json:ISuperObject;Field:TField):Boolean;
    class function GetValue2Field(Field:TField;JsonValue:ISuperObject):Variant;
end;
implementation
uses TypInfo,encddecd;

{ TTableJSon }

class function TTableJSon.CDSFromJSon(CDS: TClientDataSet;
Json: ISuperObject): Boolean;
var
ColsJson:ISuperObject;
begin
Result := False;
if Json = nil then
    Exit;
CDS.Close;
CDS.Data := Null;
//创建字段
ColsJson := Json.O[cstCols];
CreateFieldByJson(CDS.FieldDefs,ColsJson);
if CDS.FieldDefs.Count >0 then
    CDS.CreateDataSet;
ImportDataFromJSon(CDS,Json.O[cstData]);
Result := True;
end;

class function TTableJSon.CreateFieldByJson(Fields: TFieldDefs;
ColsJson: ISuperObject): Boolean;
var
SubJson:ISuperObject;
ft:TFieldType;
begin
Result := False;
Fields.DataSet.Close;
Fields.Clear;
for SubJson in ColsJson do
begin
    ft := TFieldType(GetEnumValue(TypeInfo(TFieldType),'ft'+SubJson.S[cstFieldType]));
    if ft= ftAutoInc then //自增字段不能录入，必须更改
      ft := ftInteger;
    Fields.Add(SubJson.S[cstFieldName],ft,SubJson.I[cstFieldSize],SubJson.B[cstRequired]);
end;
Result := True;
end;

class function TTableJSon.CreateJsonValue(Json: ISuperObject;
const Name: string; const Value: Variant): Boolean;
begin
Result := False;
Json.O[Name] := SO(Value);
Result := True;
end;

class function TTableJSon.CreateJsonValueByField(Json: ISuperObject;
Field: TField): Boolean;
begin
Result := False;
if Field Is TDateTimeField then
    Json.O[Field.FieldName] := SO(Field.AsDateTime)
else if Field is TBlobField then
    Json.S[Field.FieldName] := EncodeString(Field.AsString)
else
    Json.O[Field.FieldName] := SO(Field.Value);
Result := True;
end;

class function TTableJSon.GetValue(
Json: ISuperObject;const Name: string): Variant;
begin
case Json.DataType of
    stNull: Result := Null;
    stBoolean: Result := Json.B[Name];
    stDouble: Result := Json.D[Name];
    stCurrency: Result := Json.C[Name];
    stInt: Result := Json.I[Name];
    stString: Result := Json.S[Name];
end;
end;

class function TTableJSon.GetValue2Field(Field: TField; JsonValue:ISuperObject): Variant;
begin
if JsonValue.DataType = stNull then
    Result := Null
else if Field is TDateTimeField then
    Result := JavaToDelphiDateTime(JsonValue.AsInteger)
else if (Field is TIntegerField) or (Field is TLargeintField) then
    Result := JsonValue.AsInteger
else if Field is TNumericField then
    Result := JsonValue.AsDouble
else if Field is TBooleanField then
    Result := JsonValue.AsBoolean
else if Field is TStringField then
    Result := JsonValue.AsString
else if Field is TBlobField then
    Result := DecodeString(JsonValue.AsString)    

end;

class function TTableJSon.ImportDataFromJSon(DataSet: TDataSet;
DataJson: ISuperObject): Integer;
var
SubJson:ISuperObject;
i:Integer;
iter: TSuperObjectIter;
begin
if not DataSet.Active then
    DataSet.Open;
DataSet.DisableControls;
try
    for SubJson in DataJson do
    begin
      DataSet.Append;
      if ObjectFindFirst(SubJson,iter) then
      begin
         repeat
           if DataSet.FindField(iter.Ite.Current.Name)<>nil then
             DataSet.FindField(iter.Ite.Current.Name).Value :=
                GetValue2Field(
                DataSet.FindField(iter.Ite.Current.Name),
                iter.Ite.Current.Value);
         until not ObjectFindNext(iter) ;
      end;
      DataSet.Post;
    end;
finally
    DataSet.EnableControls;
end;
end;

class function TTableJSon.JSonFromDataSet(DataSet:TDataSet):string;
procedure GetFieldTypeInfo(Field:TField;var Fieldtyp,JsonTyp:string);
begin
    Fieldtyp := GetEnumName(TypeInfo(tfieldtype),ord(Field.DataType));
    Delete(Fieldtyp,1,2);
    if Field is TStringField then
      JsonTyp := 'string'
    else if Field is TDateTimeField then
      JsonTyp := 'integer'
    else if (Field is TIntegerField) or (Field is TLargeintField) then
      JsonTyp := 'integer'
    else if Field is TCurrencyField then
      JsonTyp := 'currency'
    else if Field is TNumericField then
      JsonTyp := 'double'
    else if Field is TBooleanField then
      JsonTyp := 'boolean'
    else
      JsonTyp := 'variant';
end;
var
sj,aj,sj2:ISuperObject;
i:Integer;
Fieldtyp,JsonTyp:string;
List:TStringList;
begin
sj := SO();
//创建列
aj := SA([]);
List := TStringList.Create;
try
    List.Sorted := True;
   
    for i := 0 to DataSet.FieldCount - 1 do
    begin
      sj2 := SO();
      GetFieldTypeInfo(DataSet.Fields[i],Fieldtyp,JsonTyp);
    
      sj2.S[cstFieldName] := DataSet.Fields[i].FieldName;
      sj2.S[cstFieldType] := Fieldtyp;
      sj2.S[cstJsonType] := JsonTyp;
      sj2.I[cstFieldSize] := DataSet.Fields[i].Size;
      sj2.B[cstRequired] := DataSet.Fields[i].Required;
      sj2.I[cstFieldIndex] := DataSet.Fields[i].Index;
      aj.AsArray.Add(sj2);
      List.Add(DataSet.Fields[i].FieldName+'='+JsonTyp);
    end;
    sj.O['Cols'] := aj;
    //创建数据集的数据
    DataSet.DisableControls;

    DataSet.First;
    aj := SA([]);
    while not DataSet.Eof do
    begin
      sj2 := SO();
      for i := 0 to DataSet.FieldCount - 1 do
      begin
        //sj2.S[IntToStr(DataSet.Fields[i].Index)] := VarToStrDef(DataSet.Fields[i].Value,'');
        if VarIsNull(DataSet.Fields[i].Value) then
          sj2.O[DataSet.Fields[i].FieldName] := SO(Null)
        else
        begin
          CreateJsonValueByField(sj2,DataSet.Fields[i]);
        end;
      end;
      aj.AsArray.Add(sj2);
      DataSet.Next;
    end;
    sj.O['Data'] := aj;

    Result := sj.AsString;
finally
    List.Free;
    DataSet.EnableControls;
end;

end;

end.

调用示例：

//数据集转JSON对象或JSON文本

var
json:TTableJSon;
s:string;

begin

S := json.JSonFromDataSet(ADODataSet1);

//在用TStringStream读入字符串S，存成文本，看看其格式.

end;

//JSON对象或文本，装载到数据集

     至于SuperObject的详细用法，万一老师已经很描述很清楚。最新版的1.2.1，添加了currency属性，也支持D2010，包括最新的RTTI。

     SuperObject看起来很容易上手，但有一些概念必须理解清楚，比如数组的创建和使用、空值如何赋值等。以下就讲讲SuperObject一些特殊的用法：

1、JSON数组。创建数组有两种方式，一个是 TSuperObject.Create(stArray)，另外一种是用接口方式 SA([]);

最常用的是后面一种。数组JSON对象转换AsArray方法，然后使用ADD或其length等方法或属性；数组加入JSON对象，JSON对象必须以O的属性支持赋值；范例如下：

//////这个范例是创建列的元信息

var
sj,aj,sj2:ISuperObject;
i:Integer;
Fieldtyp,JsonTyp:string;
List:TStringList;
begin
sj := SO();//创建JSON对象
aj := SA([]);//创建数组

   for i := 0 to DataSet.FieldCount - 1 do
    begin
      sj2 := SO();//创建列的信息，数组里的子对象
      //GetFieldTypeInfo(DataSet.Fields[i],Fieldtyp,JsonTyp);//获取字段信息，以及对应的JSON字段信息，可以忽略不看
     
      sj2.S[cstFieldName] := DataSet.Fields[i].FieldName;
      sj2.S[cstFieldType] := Fieldtyp;
      sj2.S[cstJsonType] := JsonTyp;
      sj2.I[cstFieldSize] := DataSet.Fields[i].Size;
      sj2.B[cstRequired] := DataSet.Fields[i].Required;
      sj2.I[cstFieldIndex] := DataSet.Fields[i].Index;
      aj.AsArray.Add(sj2);// 数组转换，必须用 AsArray
      List.Add(DataSet.Fields[i].FieldName+'='+JsonTyp);
    end;
    sj.O['Cols'] := aj;//数组添加到JSON对象，必须以对象方式

end;

2、如何处理空值NULL。空值是强类型数据下一种未赋值或未知的值。下面是SuperObject 的数据类型，看看字面意思也就大概明白。 TSuperType = (
    stNull,
    stBoolean,
    stDouble,
    stCurrency,
    stInt,
    stObject,
    stArray,
    stString
    ,stMethod );

    SO()接口方法有好多Overload方法，其中

function SO(const value: Variant): ISuperObject; overload

就包含了空值的处理。同样，空值也是一种属性对象，因此，我们必须这样赋值：

SJ.O['Name'] := SO(NULL); 在使用之前，最好先判断 ISuperObject 值 的 datatype是否为 stNull

3、从文件获取JSON对象。ISuperObject不能直接从文件导入JSON信息，必须借助实体类TSuperObject。

var
sj:ISuperObject;
begin
    sj := TSuperObject.ParseFile('Json.txt');

end;