这个批处理看了下，很有创意。（没找到原连接，但代码中有名字）

原理是这样：

help：命令查询cmd命令列表

help cmd：命令查询具体的描述

然后以html的相关格式写进超文本文件。

但也因此资料是不完全的，譬如最常用的net等命令不会被攫取。

-------------------------------------------以下代码存入*.bat------------------------------------

@echo off
del CMD命令速查手册.htm >nul
echo.===============================
echo......请稍候，构造htm文件中.....
echo.===============================
>CMD命令速查手册.htm echo ^<head^>
>>CMD命令速查手册.htm echo ^<title^>CMD命令速查手册^</title^>
>>CMD命令速查手册.htm echo ^<meta http-equiv="Content-Type" content="text/html^; charset=gb2312" ^/^>
>>CMD命令速查手册.htm echo ^</head^>
>>CMD命令速查手册.htm echo ^<A NAME="Top"^>
>>CMD命令速查手册.htm echo ^<center^>
>>CMD命令速查手册.htm echo ^<h1^>CMD 命令速查手册^</h1^>
>>CMD命令速查手册.htm echo Written by Asheng    %date%
>>CMD命令速查手册.htm echo ^</center^>
>>CMD命令速查手册.htm echo ^<br^>
ver|find "Windows XP" && goto:joke
for /f "tokens=1*" %%i in ('help^|more +3') do (
help %%i>nul && echo ^<a href="#%%i"^>%%i^</a^>^ ^ %%j >>CMD命令速查手册.htm || echo ^ ^ ^ ^ %%i %%j>>CMD命令速查手册.htm
>>CMD命令速查手册.htm echo ^</br^>
)
for /f %%i in ('help^|more +3') do (
help %%i>nul && (
>>CMD命令速查手册.htm echo ^<a name="%%i"^>
>>CMD命令速查手册.htm echo ^<h2^>%%i^</h2^>
>>CMD命令速查手册.htm echo ^<pre^>
help %%i>>CMD命令速查手册.htm
>>CMD命令速查手册.htm echo ^</pre^>
>>CMD命令速查手册.htm echo ^<a href="#top"^>返回页首^</a^>
)
)
start CMD命令速查手册.htm
goto:eof
:joke
for /f "tokens=1*" %%i in ('help^|more +1') do (
help %%i>nul && echo ^ ^ ^ ^ %%i %%j>>CMD命令速查手册.htm || echo ^<a href="#%%i"^>%%i^</a^>^ ^ %%j >>CMD命令速查手册.htm
>>CMD命令速查手册.htm echo ^</br^>
)
for /f %%i in ('help^|more +1') do (
help %%i>nul || (
>>CMD命令速查手册.htm echo ^<a name="%%i"^>
>>CMD命令速查手册.htm echo ^<h2^>%%i^</h2^>
>>CMD命令速查手册.htm echo ^<pre^>
help %%i>>CMD命令速查手册.htm
>>CMD命令速查手册.htm echo ^</pre^>
>>CMD命令速查手册.htm echo ^<a href="#top"^>返回页首^</a^>
)
)
start CMD命令速查手册.htm

-------------------------------------------以上代码存入*.bat------------------------------------

Monyer