{value
    let frame:Frame = {Frame margin = 30pt, "Interior Text"}
    let vbox:VBox = {VBox background = "yellow", frame}
    let menubar:MenuBar =
        {MenuBar
            {SubMenu label = {text Change {underline T}ext},
                key-access = 'T',
                {MenuAction
                    label = {text {underline a}pples},
                    key-accel-string = "Ctrl+A",
                    key-access = 'a',
                    {on Action do
                        {frame.add replace?=true, "apples"}
                    }
                },
                {MenuAction
                    label = {text {underline b}read},
                    key-accel-string = "Ctrl+B",
                    key-access = 'b',
                    {on Action do
                        {frame.add replace?=true, "bread"}
                    }
                }
            },
            {SubMenu label = {text Change {underline C}olor},
                key-access = 'C',
                {MenuAction label = {Frame background = "red",
                                        width = 0.5in,
                                        height = 0.25in},
                    key-access = 'r',
                    key-accel-string = "F2",
                    {on Action do
                        set vbox.background = "red"}
                },
                {MenuAction label = {Frame background = "blue",
                                        width = 0.5in,
                                        height = 0.25in},

                    key-accel-string = "F3",
                    {on Action do
                        set vbox.background = "blue"}
                }
            }
        }

    {vbox.add before=frame, menubar}

    let v:View =
        {View
            vbox,
            {on e:WindowClose at v:View do
                {e.consume}
                {v.hide}
            }
        }

    {CommandButton label = "Show new view",
        {on Action do
            {v.show}
        }
    }
}