好友DYQ最近琢磨Envi分块问题,研究的很深. 今天LuoLuo让找找ITT官方资料,以下是一点点收获. E文的,勉强看吧~~~

Topic:

From the main ENVI menu, under File -> Preferences -> Miscellaneous, users are able to set Cache Size and Image Tile Size. This tip discusses what these settings mean.

Discussion:

In order for ENVI to process images that are much larger than the total amount of RAM available on the system, large images are broken into pieces that are small enough for the system to handle. Each piece is called a tile, and when the image is processed, only one tile is read into memory at a time. The Image Tile Size setting in the ENVI configuration file determines the size for the tile, and thus how much of an image is read into RAM and processed at a time. If the entire image is smaller than the Image Tile Size setting, then the entire image is processed in one tile. When processing on one tile is finished, ENVI releases that tile抯 memory, and then reads the next tile for processing. If ENVI tries to read in a tile that is larger than the amount of contiguous RAM available on your machine at the time you start a process, then you will get the error: "unable to allocate memory to make array." Even if you have a very large amount of RAM, it is important to remember that each tile must fit into a contiguous section of memory. Because RAM quickly becomes fragmented, it is dangerous to have a large tile setting. So, for the tile size, smaller is better. Because the Image Tile Size setting has very little effect on performance, we recommend that it be kept at the default value of 1 MB, and suggest that it never exceed about 4 MB.

There is one case in which ENVI will use a tile size that is different than the Image Tile Size setting in the configuration file. When spectral processing is being performed, the tile size will be equal to the number of samples times the number of bands, regardless of the tile size setting. So, for spectral processing it is possible for the tile to exceed the tile size setting, although this is rarely the case. In fact, spectral tiles are usually smaller than the configuration file抯 tile size setting.

The Cache Size setting in the ENVI configuration file does not directly affect memory allocation, but it helps ENVI keep an eye on how much RAM is likely to be available. The cache size is specified because IDL does not have any way to know how much RAM is available on your machine. When you set the cache size it tells ENVI that when you have used up that much RAM, ENVI should start to remove unnecessary items from RAM to make more available (sometimes ENVI will keep certain kinds of data in RAM to speed performance, although these are not required for ENVI to run and can be released if memory is low). The cache setting is not a fixed upper limit on the amount of RAM that ENVI will use, it is just a benchmark that ENVI uses to gauge whether the amount of RAM you have used up is a little or a lot. It is configurable because of the wide variety of RAM on different machines.

If your Cache Size setting is large, then ENVI will not start cleaning up RAM until that large amount of RAM has been used. This means that less RAM will be left available for further processing. To minimize your chances of starting a process and then running out of RAM in the middle of a process (when ENVI can't clear RAM), you want to have a reasonable amount of RAM available even after your cache is full. On single-user machines, we recommend that the cache be set to 50-75% of the available physical RAM on the system. For example, if you have 80 Mb of RAM, then a reasonable cache size might be 40-60 MB. For multi-user systems (such as UNIX workstations) the cache size should be reduced to reflect the amount of physical RAM that will typically be available. Generally, it is best to err on the side of a smaller cache size.

看了DYQ回复，觉得有道理，还是总结一下吧：

上边大概就是说，TileSize是分块数据的存储量，要申请连续内存，不宜过大，1M足够，最好不要超过4M，这个参数对Envi执行效率的影响不大。

Cache是告诉Envi有多少内存可用，一般设置物理内存总数的50%-70%。当Envi要使用的内存超过Cache时，会自动释放不必要的内存占用。如果Cache设置过高，这个机制很难被激活，可能会导致Envi占用内存过多。

组里的答案是：除了重置进程，或者重启IDL，自定义的系统变量不可能删除。IDL帮助里讲了：IDL的系统变量在系统底层都有预定义的，无法修改的类型。

解决办法：如有必要，自定义指针类型的系统变量。

总结：系统变量慎用。最好不要放置大数据的东西。存个路径，参数啥的就够了。

转测试代码：

1：无法删除的系统变量

IDL> DefSysV, '!TESTER', 5
IDL> DelVar, !TESTER
% DELVAR: Expression must be named variable in this context: <INT
( 5)>.

IDL> Undefine, !Tester
IDL> Help, !Tester
<Expression> INT = 5

2：改指针类型

IDL> defsysv, '!tester', Ptr_New(5)
IDL> help, !tester
<Expression> POINTER = <PtrHeapVar1>
IDL> help, *!tester
<PtrHeapVar1> LONG = 5
IDL> Ptr_Free, !tester
IDL> !tester = Ptr_New(/Allocate_Heap) ; 重新预分配内存
IDL> help, !tester
<Expression> POINTER = <PtrHeapVar2>
IDL> help, *!tester
<PtrHeapVar2> UNDEFINED = <Undefined>
IDL> help, /heap
Heap Variables:
# Pointer: 1 ; 因为预分配内存了，所以还是显示有一个有效指针
    # Object : 0
<PtrHeapVar2> UNDEFINED = <Undefined>
IDL> Ptr_Free, !tester ; 释放了，就没有了。
IDL> help, /heap
Heap Variables:
# Pointer: 0
# Object : 0

看到CG新写一篇 《OR 和 II》 ，CQ老大都跟帖了，我也来参合一把。以下是小小心得。仅供讨论~~

-----------------------------------------------------------------------------------------------------------------------------------

通常在做“或”逻辑判断时用到这两个运算符。

区别：

2：运算机制

Or   对Or的两边参数，逐位比较。这就要求两个参数都有效才行。这就是CG文章里下述问题的解释。

        IDL> a=1

        IDL> print,a or b ; 错误！ B参数无效！
                Variable is undefined: B.
                 Execution halted at: $MAIN$

||    采用Short-circuiting方式，逐个参数判断真假，只要出现真，就停止。这意味着：

        除了第一个参数，其余参数不一定有效都行。这就是CG文章里，下述问题的解释。  

         IDL> a=1       
        IDL> print,a || b
               1          ; 正确！因为第一个参数a有效，而且a为真，本次逻辑判断有结果了！
   
         IDL> print,b || a ; 错误！因为第一个参数b无效！
                 Variable is undefined: B.
                 Execution halted at: $MAIN$

总结：

      Or 比 || 强大，比||较真(CG) ， 但是 || 判断效率更高（因为有Short-circuiting）建议IF等逻辑判断时，用||。

重装IE8也不管用，查了好多，都说修复吧，修复。难道只能修复？

又找了些老外的坛子，看来有门道：

问题一致：Internet Explorer is currently running with add-ons disabled，大致描述了他是多么多么的无奈，多么多么的痛苦，就是解决不了，来坛子里讨教来了。

回答的有说关杀软，关防火墙，连重装系统也有人说。

最后，总算有明白人来了：其实是IE快捷方式的问题。

解决办法：删除所有IE快捷方式，替换为c:\Program Files\Internet Explorer\iexplore.exe

以下节选部分重点楼层：

ESRI就是ESRI，老大就是老大。号召力是很强的，很多讲座都人满为患，制图那场，去得有点晚，只能站着听了。。

我很少有兴趣和陌生人合影，但这次见到ITTVIS总裁Richard w.Cooke，这个管理着我年年月月，天天都在使用的Envi/IDL的人，还是有点小激动，和QQZ一起跑上去找人合影，哈哈。 同时还有亚洲区副总裁Sinn。

这次大会，Envi/IDL和Arcgis的互操作，一体化介绍还是比较出彩的。相信很多人都比较感兴趣。看看体验区来咨询的人就知道了。

回公司晃了一下，虽然离开几年了，但一切都很熟悉，一进大门，就把每个楼层逛在脑子里逛了一遍。到了CG的部门，一眼望见一排专业的IDL程序员，专心致志的写着代码，估计这场面，整个中国，不超过两三家公司能有。大部分写IDL的，都是散兵游勇。看着正在辛勤工作的IDLer们，不由得想起了当初在这奋战的日子。。。虽然多是辛苦的记忆，但仍然很怀念。

又和大家(QQZ,CG,DYQ,Baozi,WZC, LL...)聚到一起，详谈甚欢。交流很多东西，收获颇丰。CG，QQZ，DYQ展示了不少好东西，香蕉的Demo不错，可惜有点抠门，拿不到。我给他看了几个Envi的外挂，也没给他。哈哈～～

总结，明确了自己的一些思路。以后要向行业主流方向，主流技术靠拢。

特别鸣谢QQZ，免了我落单之苦。

照片1：左起，QQZ, HH, Richard, Shin

照片2：左起，HH, Richard, Shin

文本里有记录以下下一行字符：

1000(H) 272 1567 3120 4333 5725 7348 9327 10539 12012 13866 16378

如何分开读取前7个字符和后面所有数字？

：：：：：我是分割线：：：：：

IDL读取二进制文件，可以用Point_Lun进行定点读取，但是文本文件就不行了。

上面这个问题，可以先整行读取，然后用字符串操作进行分解。

但我想试试读取时，就分解了。用格式化读入的办法可行。

测试代码：（文件里存的就是上述问题提到的那行字符串）

pro JumpReadTxt
file ='c:\Huxz\Temp\Test.txt'
;open file
openr, lun, file, /get_lun
   fmt = '(a7, 1x, a)' ; 先读7个字符，跳一个字符位，连续读入本行剩下的所有字符
   record = {head:'', dataS:''}
readf, lun, record, format=fmt
help, record, /stru
dataL = Long(Strsplit(record.dataS, ' ', /extract))
help, dataL
print, dataL
;close input file
free_lun,lun
end

题目：1到9，9个数，组成任意4位数，乘于一个一位数，得到的结果，正好是剩下的4个数，条件：9个数必须都用到，但不能重复。

网上有些代码，但据DYQ的调查，有的要10秒左右才能算出来。用了8重循环。但人家肯定也有些更妙的方法，比如用C写，可能要快很多。

我用IDL搞了一个方法，用了5重循环，充分利用了IDL的数组操作优势。最后速度还是可以的。我的破机器上，也就0.5秒左右。套用QQZ的一句：“VC想要和IDL比速度，都要掂量掂量自己的水平”不过，IDL也不是随便乱写就出效率的。总之所有语言都不错。存在即有理。看怎么用了。

下边是源代码，大家看看能不能把5重循环再减少几个。。。。。

源码：

Function SetDifference, a, b
mina = Min(a, Max=maxa)
minb = Min(b, Max=maxb)
if (minb gt maxa) or (maxb lt mina) then Return, a ;No intersection...
r = Where((Histogram(a, Min=mina, Max=maxa) ne 0) and $
          (Histogram(b, Min=mina, Max=maxa) eq 0), count)
if count eq 0 Then RETURN, -1 else Return, r + mina
End
;+-------------------------------------------------------------------------------------------------
Pro test
arr = Lindgen(9) + 1
timelabel = Systime(/sec)
for i=0, 8 do begin
   a = arr[i]
   for j=0, 8 do begin
    aa = arr[j]
    if a eq aa then Continue
    for k=0, 8 do begin
     aaa = arr[k]
     if aaa eq a or aaa eq aa then Continue
     for m=0, 8 do begin
      aaaa = arr[m]
      if aaaa eq a or aaaa eq aa or aaaa eq aaa then Continue
      na = a * 1000 + aa * 100 + aaa * 10 + aaaa
      for n=0, 8 do begin
       nb = arr[n]
       if nb eq a or nb eq aa or nb eq aaa or nb eq aaaa then Continue
       used = [a, aa, aaa, aaaa, nb]
       cs = SetDifference(arr, used)
       pu = na * nb
       parr = [pu/1000, (pu mod 1000) / 100, (pu mod 100) / 10, pu mod 10]
       if ARRAY_EQUAL(parr[sort(parr)], cs[sort(cs)]) then $
        print, Strtrim(na, 2) + ' * ' + Strtrim(nb, 2) + ' = ', Strtrim(pu, 2)
      endfor
     endfor
    endfor
   endfor
endfor
print, '遍历时间： ', Systime(/sec) - timelabel
End

“如何创建一个数组：大小是127×127，每行都由1至127的数字组成？不能用循环。”

刚想折腾一下，包子就说到了“##”操作符.

马上测试，答案如下：

arr = (Intarr(1, 127)+1) ## (Indgen(127)+1)

后来发现，包子对这个早有研究：

http://hi.baidu.com/bobby730/blog/item/24fa61d8f8bbe63632fa1c1d.html

注：

## 操作符的描述参看帮助。我就秉承懒人作风。不写了。

“想获取NDVI图像达到某一个百分率的DN值，但是ENVI_STATS_DOIT只能提供hist，是个一维数组，只存了所有DN对应的象元数目。
比如某一个DN值对应的象元数有1000个，我怎么得到这个DN值是多少？”

我的回答：

由于直方图是按照DN值从小到大，按组距递增排列的。所以，知道像元个数后，先找到这个个数，是直方图数组的第几个元素，然后通过 (DMin + N * BinSize) 得到DN值。其中，N代表该像元个数在直方图数组的第N个。

问题来了，
Envi的统计函数：ENVI_STATS_DOIT，可以直接得到DMin，N也可以用Where函数去Hist数组里找。
但是BinSize怎么办？ 这个统计函数，有个隐藏参数：BinSize，专门输出这个值。
例子：
envi_doit, 'envi_stats_doit', fid=fid, pos=pos, $  
dims=dims, comp_flag=3, dmin=dmin, hist=hist, BINSIZE=BINSIZE

留意上述语句的最后一个关键字参数：输出BinSize

；----------------------------------------------------------------------------------------

关于直方图，其实还有一个隐藏参数NBins，指直方图统计时的分组个数。

另外，Envi的隐藏函数，隐藏参数简直数不胜数。绝对一个大宝库。

大卫的网站被和谐后，给很多IDLer带来了不便。不能及时访问到大卫老兄的最新发布。这里转来一些大卫老兄的好东西，分享给大家。不翻译了，懒。。。

Using Numbers as Symbols

QUESTION: I would like to display a normal IDL line plot, but instead of using a symbol to represent each point, I would like to use a number. Is this possible in IDL?

ANSWER: Yes, it is possible to do this. Here is an example of the kind of code you might have to write. First, let's create some data to plot.

x = Indgen(50)
   y = RandomU(-3L, 50) * 100

And now we plot the data. Notice that we are going to create a space for the numbers by first overplotting a blank space where we can write the numbers.

Plot, x, y, BACKGROUND=FSC_Color('ivory'), COLOR=FSC_Color('navy')
   OPlot, x, y, COLOR=FSC_Color('ivory'), PSYM=SymCat(15), SYMSIZE=2.0
   XYouts, x, y, StrTrim(Sindgen(50)+1, 2), COLOR=FSC_Color('red'), $
        ALIGN=0.5, CHARSIZE=0.75

You can see the result of the code above in the figure below.

An IDL plot with numbers used in place of symbols.

细说：给Envi写外挂是最简单的Envi二次开发方式，怎么操作？

背景知识：http://hi.baidu.com/dyqwrp/blog/item/5b6c6ac45edbf6a18326ac7a.html

Envi   帮助：ENVI_DEFINE_MENU_BUTTON， 看Example

如何运行Example？

直接把Example拷贝到IDLE，保存编译后Save，放到Save_Add，那是啥效果也没有的

怎么回事？？Envi的帮助里，关于这个ENVI_DEFINE_MENU_BUTTON，在最前面有这么几句：

Use this procedure to add menu items (buttons) to the ENVI menu system from a user-defined procedure in a .pro or .sav file within the save_add directory. The .pro or .sav file must contain a procedure named filename_define_buttons, where filename is the name of that file. For instance, if the file in the save_add directory is named my_process.pro, a procedure named my_process_define_buttons.pro should be in that file to allow you to add buttons to the ENVI menu system. The filename_define_buttons procedure has only one argument and no keywords, as shown in the following example code:
PRO my_process_define_buttons, buttonInfo
;
; Define Buttons with ENVI_DEFINE_MENU_BUTTON
;
END

这几句详细讲了使用ENVI_DEFINE_MENU_BUTTON的规则。

总结：按钮定义Pro的命名最为关键：为，主程序名 + _define_buttons, buttonInfo

           解释：主程序：程序的入口，与Pro文件名同名的程序。

土地利用类型转换（变化）混淆矩阵

查阅相关的资料，也没有得到土地利用类型转换矩阵确切的定义，我理解为不同时间段内同一区域内土地利用类型的相互转换关系，一般用二维表来表达，从二维表中可以快速查看各个地类间相互转化的具体情况。 比如某一类别的土地有百分之多少（或者面积）分别转化成了其他的土地类型，现在某类型的土地分别是由过去的哪些类别转化而来的等等。还可以生成变化统计栅格图（掩膜图像），它描述了前后两幅土地分类图之间的地类发生转变的位置和类别。
土地利用类型转换矩阵可以从两幅栅格图中计算得到，也可以从两个矢量文件中计算获得。下面介绍在ENVI下从两幅分类结果的栅格图中计算土地利用类型转换矩阵。
1、准备数据
两个时相的土地利用分类结果，它是单波段、专题类型的伪彩色图像（ENVI Classification）。
2、计算转换矩阵
打开两个土地利用分类结果。
（1） 在主菜单中，选择Basic Tools → Change Detection → Change Detection Statistics。
（2）分别在Initial State对话框和final state对话框中选择前一时相和后一时相的土地利用结果。
（3） 在Define Equivalent Classes对话框中（图1），如果两个土地利用分类名称一致，系统自动将Initial State Class和Final State Class对应，否则手动选择，单击Add Pair按钮选择。
（4） 选择对应的地物类型之后，单击OK按钮，出现图2对话框。选择生成图表表示单位（Report Type）：像素（Pixels）、百分比（Percent）和面积（Area）。选择Output Classification Mask Images?为YES，输出掩膜图像，选择输入路径及文件名。
（5） 单击OK，执行土地利用类型转换矩阵计算过程。

图1 Define Equivalent Classes对话框
     

                         图2 选择数据参数

3、查看结果
    （1）如图3为得到的土地利用类型转换矩阵结果。横字段表示前一时间段（Initial State）的土地利用类别，纵字段为后一时间段（Final State）的土地利用类别。横字段和纵字段交叉处表示变化值，如有2520900平方米林地用地变化为草地。

图3 土地利用类型转换矩阵

    （2） 还可以为每一个地类生成一个变换掩膜图像，图4所示为其中一个地类的掩膜图像。掩膜图像的灰度值表示变化类型，如这里的2{草地}表示林地变化为草地的像元。

   图4 变化掩膜图像

大家直接拷贝到IDL编译器看吧。

Pro testStructure
; By Huxz, CUHK, 2009-6
;------------命名结构体--------------------------------------------------------------------------
; 定义结构体,相当于定义一个类。这也是为什么类的__Define过程也必须是一个命名结构体
a = {name1, a:1, b:'a'} ; 其实这些值对之后的实例化，是没有任何用处的。。。
; 将上面定义的类，实例化一个对象：B
b = {name1}
; 查看 B的内容
print, '回到纯真。。。'
help, b, /stru
; 什么？为啥结构体被初始化了？数值变成0，字符串变成'' 了？那是因为没有初始化：
; 再来一例，并给定初始值：2, 3
print, '初始化的效果。。。'
bb = {name1, 3, 'b'}
help, bb
; 总结：定义命名结构体其实和定义一个类是同一原理。
; 一个命名结构体，就是一个只有定义，只有初始化，而没有方法的类
;--------------------------------------------------------------------------------------------------

;------------匿名结构体--------------------------------------------------------------------------
print, '没有名字，无法实例化的匿名结构体。。。'
c = {a: 1, b: 'test'}
help, c, /stru
; 想实例化？没门。匿名结构体只能每次定义，不能一次定义，到处实例化。

; 最后，为什么说一个命名结构体就是一个类的原型？看看下一行代码的报错信息吧！
; 我们用实例化命名结构体的方法来实例化一个根本不存在的命名结构体，看会怎么样？
; 看到Attempt to call undefined procedure/function: 'FBC288__DEFINE'.没？
; 是不是很眼熟？？？ ^_^
print, '看看这个错误信息，是不是证明 初始化一个命名结构体，和初始化一个类是一个原理？'
d = {fbc288}
End

http://www.rayfile.com/files/02970fa8-50b0-11de-92a8-0014221b798a/

我写的一个小例子，注意看注释理解。

; 直接图形法下颜色指定
; By HH CUHK
Pro TestDirectColors
; 注意这里：按列看，第一列是黑色，第二列是红色。。
r = [0, 255, 255, 0,   0,   0,   255, 255]
g = [0, 0,   255, 255, 255, 255, 0,   255]
b = [0, 0,   0,   0,   255, 255, 255, 255]
;   载入自定义颜色：从1开始编号。
TVLCT, r, g, b, 1
Erase, COLOR=8 ; 刷新背景色，8号颜色：白色：第8列颜色；背景色也可以直接指定!P.BackGroud = 8
p = [0.15, 0.15, 0.9, 0.9] ; Position of the plot in the window.  
    Plot, findgen(11), COLOR=2, $ ; 线颜色：2号色：红色：第2列颜色
       POSITION=p, /NOERASE
End

大卫的答案：

QUESTION: I'd like to have a color background on my plot. I know about using the Background keyword to establish the background for the display window, but that's not what I am talking about. I want just the area of the plot enclosed by the axes in a different color. I've tried adding this background with the Polyfill command, but then my plot tick marks disappear. Is there a better way to do this?

ANSWER: If you position your plot with the Position keyword, then you can draw your background polygon first into that position, then draw your plot with the NoErase keyword set. (You might want to erase the window first with the Erase command, since with this method you will be losing the Plot command's ability to erase whatever is currently in the window before it draws. This would be a good time to get the area outside the polygon the color you want, since you can use the Color keyword here as well.) Here is an example of what I mean.

p = [0.15, 0.15, 0.9, 0.9] ; Position of the plot in the window.
   Erase, COLOR=FSC_COLOR('papaya')
   PolyFill, [p[0],p[0],p[2],p[2],p[0]], $
             [p[1],p[3],p[3],p[1],p[1]], $
             COLOR=FSC_COLOR('tan'), /NORMAL
   Plot, findgen(11), COLOR=FSC_COLOR('dark red'), $
      POSITION=p, /NOERASE
   PlotS, findgen(11), findgen(11), PSYM=2, $
      COLOR=FSC_COLOR('royal blue')

Executing these command results in the following figure. (You will need the FSC_Color program from the Coyote Library to run the code.)

A plot with a colored background inside the axes.

Note that direct graphics commands just put pixels on top of pixels, so sometimes you have to "layer" your graphics commands to achieve the results you want. The NoErase keyword is a great help when you are re-drawing axis tick marks and the like.

Adding Backgrounds with Multiple Plots

QUESTION: Well, sure, this works fine for a single plot. But what if I am drawing multiple plots using !P.MULTI? It doesn't work at all then. How can I do the same thing with multiple plots?

ANSWER: Ah, then you have to be a little more clever than you were before. Two pieces of information are required. First, every time you issue a graphics command that would, on its own, erase the window, !P.MULTI adjusts the plot positioning system variables so that the plot goes into the new plot space. This makes it hard to "clean up" the plot by the layering method described above. In other words, even if you use a PLOT command with a NOERASE keyword set, the plot goes into the next space, not the space you are trying to draw it into. So you have to trick !P.MULTI into doing the right thing for you.

This brings up the second piece of information you need: the meaning of the first element of the !P.MULTI vector. !P.MULTI[0] indicates how many plots remain to be plotted on the page. So, if I have four plots on the page, and I draw the first plot, !P.MULTI[0] is set to 3, since there are three plots remaining to be plotted on the page.

IDL> !P.MULTI=[0,2,2] ; Four plots on a page.
   IDL> Plot, Findgen(11)
   IDL> Print, !P.MULTI[0]
 3
   IDL> Plot, Findgen(11)
   IDL> Print, !P.MULTI[0]
 2
   IDL> Plot, Findgen(11)
   IDL> Print, !P.MULTI[0]
 1
   IDL> Plot, Findgen(11)
   IDL> Print, !P.MULTI[0]
 0

If I am just staring to draw a plot, !P.MULTI[0] is set to 4, but since there are four plots to be plotted, this is set internally to 0 (please don't ask). Or, rather, 4 is the equivalent of 0, but it is the 0 that tells !P.MULTI to erase the page and start a new set of plots. Clear?

Don't worry about it. Trust me. Think of it like this:

!P.MULTI[0] = (Number of plots remaining to be drawn) MOD (Total number of plots)

The point is, we can manipulate !P.MULTI[0] to trick !P.MULTI into doing things for us that it didn't intend to do. That's what we are going to do to put background colors in multiple plots.

One final point, before I show you the code. You can't use positional parameters like the POSITION keyword on your plots when you are using !P.MULTI. This is because !P.MULTI is manipulating the plot position for you. If you try to do the same, the result is a muddled mess. However, you can tell where !P.MULTI positioned your plot (after it is drawn) from the !X.WINDOW and !Y.WINDOW system variables.

OK, here is the code for producing a 2 by 2 arrangement of four plots.

; Set up for 2x2 plot sequence
   !P.MULTI=[0,2,2]
   
   ; First plot. Use BACKGROUND keyword to set background for all plots.
   Plot, findgen(11), COLOR=FSC_COLOR('dark red'), BACKGROUND=FSC_COLOR('papaya')

   ; Position of the plot in the window. Fill with POLYFILL.
   p = [!X.Window[0], !Y.Window[0], !X.Window[1], !Y.Window[1]]  
   PolyFill, [p[0],p[0],p[2],p[2],p[0]], $
             [p[1],p[3],p[3],p[1],p[1]], $
             COLOR=FSC_COLOR('tan'), /NORMAL

   ; Rewind plot counter, "fix" the plot, then reset for NEXT plot.
   !P.MULTI[0] = 0
   Plot, findgen(11), COLOR=FSC_COLOR('dark red'), /NOERASE 
   PlotS, findgen(11), findgen(11), PSYM=2, COLOR=FSC_COLOR('royal blue')
   !P.MULTI[0] = 3

   ; Second plot.
   Plot, findgen(11), COLOR=FSC_COLOR('dark red')

   ; Position of the plot in the window. Fill with POLYFILL.
   p = [!X.Window[0], !Y.Window[0], !X.Window[1], !Y.Window[1]] 
   PolyFill, [p[0],p[0],p[2],p[2],p[0]], $
             [p[1],p[3],p[3],p[1],p[1]], $
             COLOR=FSC_COLOR('tan'), /NORMAL
 
   ; Rewind plot counter, "fix" the plot, then reset for NEXT plot.
   !P.MULTI[0] = 3
   Plot, findgen(11), COLOR=FSC_COLOR('dark red'), /NOERASE 
   PlotS, findgen(11), findgen(11), PSYM=2, COLOR=FSC_COLOR('royal blue')
   !P.MULTI[0] = 2

   ; Third plot.
   Plot, findgen(11), COLOR=FSC_COLOR('dark red')

   ; Position of the plot in the window. Fill with POLYFILL.
   p = [!X.Window[0], !Y.Window[0], !X.Window[1], !Y.Window[1]]   
   PolyFill, [p[0],p[0],p[2],p[2],p[0]], $
             [p[1],p[3],p[3],p[1],p[1]], $
             COLOR=FSC_COLOR('tan'), /NORMAL
 
   ; Rewind plot counter, "fix" the plot, then reset for NEXT plot.
   !P.MULTI[0] = 2
   Plot, findgen(11), COLOR=FSC_COLOR('dark red'), /NOERASE 
   PlotS, findgen(11), findgen(11), PSYM=2, $
      COLOR=FSC_COLOR('royal blue')
   !P.MULTI[0] = 1
      
  ; Fourth plot.    
   Plot, findgen(11), COLOR=FSC_COLOR('dark red')

   ; Position of the plot in the window. Fill with POLYFILL.
   p = [!X.Window[0], !Y.Window[0], !X.Window[1], !Y.Window[1]]  
   PolyFill, [p[0],p[0],p[2],p[2],p[0]], $
             [p[1],p[3],p[3],p[1],p[1]], $
             COLOR=FSC_COLOR('tan'), /NORMAL

   ; Rewind plot counter, and "fix" the plot.
   !P.MULTI[0] = 1
   Plot, findgen(11), COLOR=FSC_COLOR('dark red'), /NOERASE 
   PlotS, findgen(11), findgen(11), PSYM=2, $
      COLOR=FSC_COLOR('royal blue')

  ; Set back to single plot.
  !P.MULTI = 0

You see the result in the figure below.

A multi-plot with a colored background inside the axes of each plot.